home
***
CD-ROM
|
disk
|
FTP
|
other
***
search
/
Amiga Games: Greatest Hits 1996
/
Amiga Games: Greatest Hits 1996.iso
/
archive
/
userbox
/
publicdomain
/
superviewel.lha
/
SuperViewEL
/
SuperViewLibrary
/
Install_SVLib
< prev
next >
Wrap
Text File
|
1996-06-18
|
9KB
|
323 lines
; $VER: Install_SVLib V13.2 (26.5.96)
; © 1993-96 by Andreas R. Kleinert.
; This is the Installer Script for superview.library V13+
(set MC68x (database "cpu"))
(set @app-name "SuperView-Library")
; **************************************************************************
; Create/Update basic configuration
(makedir "ENV:SuperView-Library")
(makedir "ENVARC:SuperView-Library")
(set selectsvdriver (askchoice
(prompt "What's your basic configuration ?")
(help @askchoice-help)
(choices "ECS, no GfxCard" "AGA" "AGA (CD-32)" "Picasso II" "RetinaZ2/Z3" "Merlin-II" "OpalVision" "CyberGraphics GfxCard" "EGS7 GfxCard" "Other GfxCard (ECS/AGA)" "(do not preset anything)")
(default 1)
)
)
(if (= selectsvdriver 0) (set env_source "docs/SampleConfigs/env_ECS") )
(if (= selectsvdriver 1) (set env_source "docs/SampleConfigs/env_AGA") )
(if (= selectsvdriver 2) (set env_source "docs/SampleConfigs/env_AGA_CD32") )
(if (= selectsvdriver 3) (set env_source "docs/SampleConfigs/env_PicassoII") )
(if (= selectsvdriver 4) (set env_source "docs/SampleConfigs/env_Retina") )
(if (= selectsvdriver 5) (set env_source "docs/SampleConfigs/env_Merlin") )
(if (= selectsvdriver 6) (set env_source "docs/SampleConfigs/env_OpalVision") )
(if (= selectsvdriver 7) (set env_source "docs/SampleConfigs/env_CyberGraphics") )
(if (= selectsvdriver 8) (set env_source "docs/SampleConfigs/env_EGS7") )
(if (= selectsvdriver 9) (set env_source "docs/SampleConfigs/env_GfxCards") )
(if (<= selectsvdriver 9)
(
(copyfiles
(prompt "Copying selected configuration to ENV: ...")
(help @copyfiles-help)
(source env_source)
(dest "ENV:")
(all)
)
(copyfiles
(prompt "Copying basic GfxCard configuration to ENVARC: ...")
(help @copyfiles-help)
(source env_source)
(dest "ENVARC:")
(all)
)
)
)
(copyfiles
(prompt "Installing CPInfo files to ENVARC: ...")
(help @copyfiles-help)
(source "env")
(dest "ENVARC:")
(all)
)
; **************************************************************************
; Install main libraries
(copylib
(prompt "Installing superview.library to LIBS: ...")
(help @copylib-help)
(source "libs/superview.library")
(set svlibdir
(askdir
(prompt "Library Path")
(help @askdir-help)
(newpath)
(default "LIBS:")
)
)
(dest svlibdir)
)
(set @default-dest svlibdir)
(copylib
(prompt "Installing superviewsupport.library to LIBS: ...")
(help @copylib-help)
(source "libs/superviewsupport.library")
(dest svlibdir)
)
; **************************************************************************
; Ask for LZW
(set lzwquest (askchoice
(prompt (cat "\nIs LZW usage license-free by your countries' law ?\n\n"
"Note:\n"
"If not, LZW dependent routines will be\n"
"deactivated now. If you select Yes\n"
"nevertheless, you hereby agree to pay\n"
"any possible license fees for commercial\n"
"or other usage by yourself. If you do not\n"
"agree with that, select >Abort Install<\n")
)
(help @askchoice-help)
(choices "Yes (e.g. Germany)" "No (e.g. USA)")
(default 0)
)
)
(if (= lzwquest 0)
(
(textfile
(dest "ENV:SuperView-Library/LEGAL.controlpad")
(append "LZW=ENABLED\n")
)
(copyfiles
(source "ENV:SuperView-Library/LEGAL.controlpad")
(dest "ENVARC:SuperView-Library")
)
)
)
(if (= lzwquest 1)
(
(textfile
(dest "ENV:SuperView-Library/LEGAL.controlpad")
(append "LZW=DISABLED\n")
)
(copyfiles
(source "ENV:SuperView-Library/LEGAL.controlpad")
(dest "ENVARC:SuperView-Library")
)
)
)
; **************************************************************************
; Ask for Ghostscript
(set gsquest (askchoice
(prompt (cat "\nDo you already have Ghostscript installed ?\n\n"
"(When answering with 'Yes', you have to supply\n"
" the programs path and name here.)\n")
)
(help @askchoice-help)
(choices "Yes" "No")
(default 0)
)
)
(if (= gsquest 0)
(
(set gspath (askfile
(prompt "Path and name of Ghostscript executable")
(help @askfile-help)
(default "gs000")
)
)
(set gspathopt (cat "GS_PATH=" gspath "\n"))
(textfile
(dest "ENV:SuperView-Library/Ghostscript.controlpad")
(append gspathopt)
)
(copyfiles
(source "ENV:SuperView-Library/Ghostscript.controlpad")
(dest "ENVARC:SuperView-Library")
)
)
)
; **************************************************************************
; Install catalogs
(makedir "SYS:locale")
(makedir "SYS:locale/catalogs")
(copyfiles
(prompt "Installing OS 2.1+ catalog files ...")
(help @copyfiles-help)
(source "locale/catalogs")
(set svcatdir
(askdir
(prompt "Catalog Path")
(help @askdir-help)
(newpath)
(default "SYS:locale/Catalogs")
)
)
(dest svcatdir)
(all)
)
; **************************************************************************
; Install library modules
(set svobjectdir (tackon svlibdir "svobjects"))
(set svdriverdir (tackon svlibdir "svdrivers"))
(set svoperatordir (tackon svlibdir "svoperators"))
(makedir svobjectdir)
(makedir svdriverdir)
(makedir svoperatordir)
(copyfiles
(prompt "Installing svobjects to LIBS:svobjects ...")
(help @copyfiles-help)
(source "libs/svobjects")
(dest (tackon svlibdir "svobjects"))
(pattern "#?")
(confirm)
(files)
)
(copyfiles
(prompt "Installing svdrivers to LIBS:svdrivers ...")
(help @copyfiles-help)
(source "libs/svdrivers")
(dest (tackon svlibdir "svdrivers"))
(pattern "#?")
(confirm)
(files)
)
(copyfiles
(prompt "Installing svoperators to LIBS:svoperators ...")
(help @copyfiles-help)
(source "libs/svoperators")
(dest (tackon svlibdir "svoperators"))
(pattern "#?")
(confirm)
(files)
)
(if (>= MC68x 68020)
(
(copyfiles
(prompt "Installing special 68020+ versions of some sv-libs");
(help @copyfiles-help)
(source "libs/68030")
(dest svlibdir)
(confirm)
(all)
)
)
)
; **************************************************************************
; Modify User-Startup
(startup "SuperView-Library"
(prompt "Now modifying your S:User-Startup for VMem-Support...")
(help @startup-help)
(set vmemdir
(askdir
(prompt "Virtual Memory Path")
(help @askdir-help)
(newpath)
(default "T:")
)
)
(command "Assign VMEM: "vmemdir"\n")
)
; **************************************************************************
; Install SVPrefs
(copyfiles
(prompt "Copy SVPrefs to SYS:Prefs ?")
(help @copyfiles-help)
(source "Prefs")
(dest "SYS:Prefs")
(all)
(confirm)
)
; **************************************************************************
; Ask for Packersupport
(set ask_ps (askbool (prompt "Install PackerSupport right now ?") (help @askbool-help) ) )
(if (= ask_ps TRUE)
(
(copyfiles
(prompt "Installing Unpack.svobject to LIBS:svobjects ...")
(help @copyfiles-help)
(source "PackerSupport/Unpack-SVObject/libs/svobjects")
(dest (tackon svlibdir "svobjects"))
(pattern "#?")
(files)
)
)
)
; **************************************************************************
; Ask for SQOperators
(set ask_sq (askbool (prompt "Install SQ-Operators right now ?") (help @askbool-help) ) )
(if (= ask_sq TRUE)
(
(copyfiles
(prompt "Installing CPInfo files to ENVARC: ...")
(help @copyfiles-help)
(source "SQ-Operators/envarc")
(dest "ENVARC:")
(all)
)
(copyfiles
(prompt "Installing svoperators to LIBS:svoperators ...")
(help @copyfiles-help)
(source "SQ-Operators/libs/svoperators")
(dest (tackon svlibdir "svoperators"))
(pattern "#?")
(confirm)
(files)
)
)
)
; **************************************************************************
; EOF ;-)
(exit "SuperView-Library has been installed now.\nIf this was an Update, you should\nreboot your computer now.")